$
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$
$       --------------------   generate ursa tlp ----------------------
$
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$
$*********************************************      set basics
$
&dimen -dimen feet kips
&device -pri device  -mecho yes
&parameter -m_dis 10
$
$**********************************************************************
$**********************************************************************
$**********************************************************************
$
$      -------------    define set basics    ----------------
$
$**********************************************************************
$**********************************************************************
$**********************************************************************
$
$
$*********************************************      small number
$
&set sml = .01
&set plot = .true.
$
$*********************************************      overall data
$
&set len    := 240.                   $ctr to ctr length
&set beam   := &number(real 240-%sml) $ctr to ctr beam
$
$*********************************************      column data
$
&set cdia   :=  85.4518  $colm dia
&set ctop   := 176.8459  $height to column top
&set cbtm   :=  -0.1042  $height to column btm
&set npc    := 9         $number of points to make a circle
$
$*********************************************      pontoon data
$
&set pwidth  := 37.5492  $width of pontoon
&set ptop    := 29.0499  $height to pontoon top
&set pbtm    := -0.0842  $height to pontoon bottom
&set plmid   := 87.2746  $length of parallel midbody
&set pclnang := 45       $angle at which pontoon intersects column,
$                            $ measured from cl of pontoon
$
$**********************************************************************
$
$
$
$
$**********************************************************************
$**********************************************************************
$**********************************************************************
$
$      -------------    define macros   ----------------
$
$**********************************************************************
$**********************************************************************
$**********************************************************************
$
$
$*********************************************      macro for plots
$
&macro suplot nams
   &if %plot &then
      &selec :n -sel %nams
      &picture iso -parent :n
   &endif
&endmacro
$
$*********************************************      macro for columns
$
&macro column CN X Y -npoint poi np = 9 \
       -topelev tel top \
       -btmelev bel btm \
       -diameter di dia
   block %cn -location %x %y 00 0 -90
      &set angi = &number( real 180/(%np%-1) )
      plane %btm% %ptop%+.02 %top% -e_circ 0 0 %dia%/2 0 %angi% %np
      end
&endmacro
&m_act column block
$
$*********************************************      macro for pontoon
$
&macro pontoon cn x y z angle clen
   block %cn -location %x %y %z 0 0 %angle
      &set dcos = %cdia%*&number(cosd %pclnang%)
      &set dsin = %cdia%*&number(sind %pclnang%)
      &set d1 = &number( real (%dcos%/2) )
      &set d2 = &number( real ((%clen%-%plmid%)/2) )
      &set dd = &number( real (%cdia%*0.05) )
      &set w1 = &number( real (%dsin%) )
       &set w1 = &number( real (%w1%+(%dsin%-%pwidth%)/(%d2%-%d1%)*%dd%) )
       &set d1 = &number( real (%d1%-%dd%) )
      &set d3 = &number( real (%clen%-%d2%) )
      &set d4 = &number( real (%clen%-%d1%) )
      plane %d1%      -rect %pbtm% %ptop% %w1%
      plane %d2% %d3% -rect %pbtm% %ptop% %pwidth%
      plane %d4%      -rect %pbtm% %ptop% %w1%
      end
&endmacro
&m_act pontoon block
$
$**********************************************************************
$**********************************************************************
$**********************************************************************
$
$              -------------    generate ----------------
$
$**********************************************************************
$**********************************************************************
$**********************************************************************
$
$
$*********************************************      enter surfact menu
$
&surface
$
$*********************************************      generate a pontoon
$
pont S -%len%/2  %beam%/2 0 0 %len%
$
$*********************************************      generate two columns
$
colu sf -%len%/2  %beam%/2  -topelev %ctop -btmelev %cbtm -npoin %npc -dia %cdia
colu sa +%len%/2  %beam%/2  -topelev %ctop -btmelev %cbtm -npoin %npc -dia %cdia
$
$*********************************************      join
$
suplot
union s sf temp
delete s sf
suplot temp sa
union temp sa stbd
delete temp sa
suplot stbd
$
$*********************************************      reflect
$
reflect stbd port y
$
$*********************************************      fwd pontoon
$
pont F -%len%/2  %beam%/2 0 -90  %beam%
suplot stbd port f
$
$*********************************************      join
$
union stbd f temp
union port temp ttemp
delete stbd f port temp
suplot ttemp
$
$*********************************************      aft pontoon
$
pont a  %len%/2  %beam%/2 0 -90    %beam%
suplot ttemp a
union ttemp a tlp
suplot tlp
$
$*********************************************      rename
$
rename tlp
$
$*********************************************      emit
$
emit tlp -body tlp
emit tlp  -piece '-diftype 3ddif -cs_curr 1 1 1 -cs_wind 1 1 1'
$
$*********************************************      all done
$
end
&fini