$
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$
$       --------------------   generate a tlp ----------------------
$
$  This comi file will generate a "TLP" composed of circular
$  cylinders. All one needs to do is fill out the "basic data"
$  below. Here:
$
$  1.) len - is the length of the TLP measured from the centers of
$            the columns,
$
$  2.) beam - is the beam of the TLP measured from the centers of the
$            columns,
$
$  3.) pdia - is the diameter of the pontoons
$
$  4.) ponhgt - is the distance of the pontoons above the base of the
$               columns,
$
$  5.) npp - is the number of points used to define the circular
$            pontoon
$
$  6.) cdia - is the diameter of each column
$
$  7.) cdep - is the depth of each column, and
$
$  8.) npc - is the number of points used to define the circular
$            column
$
$  The file TLP_BLD.PPOUT contains a mesh suitable for use.
$
$
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$
$*********************************************      basic parameters
$
&dimen -dimen feet kips
&device -pri devi
$&device -pri scre
$
$**********************************************************************
$**********************************************************************
$**********************************************************************
$
$      -------------    define basic parameters    ----------------
$
$**********************************************************************
$**********************************************************************
$**********************************************************************
$
$
$*********************************************      overall data
$
&set plot = .true.
&set len    := 215   $ctr to ctr length
&set beam   := 215   $ctr to ctr beam
$
$*********************************************      pontoon data
$
&set pdia   := 30
&set ponhgt := 20    $bot of colm to bot of pontoon
&set npp    := 9
$
$*********************************************      column data
$
&set cdia   := 63    $colm dia
&set cdep   := 165   $colm depth
&set npc    := 9
$
$**********************************************************************
$**********************************************************************
$**********************************************************************
$
$      -------------    define macros   ----------------
$
$**********************************************************************
$**********************************************************************
$**********************************************************************
$
$
$*********************************************      macro for plots
$
&macro suplot nams
   &if %plot &then
      &selec :n -sel %nams
      &picture iso -parent :n
   &endif
&endmacro
$
$*********************************************      macro for columns
$
&macro column CN X Y -npoint poi np = 9 \
       -height hei height \
       -diameter di dia
   block %cn -location %x %y 00 2 -90
      &set angi = &number( real 180/(%np%-1) )
      plane 0 %ext_col %height% -circ 0 0 %dia%/2 0 %angi% %np
      end
&endmacro
&m_act column block
$
$*********************************************      macro for pontoon
$
&macro pontoon CN X Y z angle -npoint poi np = 9 \
       -length hei length \
       -diameter di dia
   block %cn -location %x %y %z 0 0 %angle
      &set angi = &number( real 180/(%np%-1) )
      plane 0 %ext_pon %length%-%ext_pon %length% \
              -circ 0 0 %dia%/2 0 %angi% %np
      end
&endmacro
&m_act pontoon block
$
$**********************************************************************
$**********************************************************************
$**********************************************************************
$
$              -------------    generate ----------------
$
$**********************************************************************
$**********************************************************************
$**********************************************************************
$
$
$*********************************************      define extra planes
$
&local ext_col = %ponhgt%+.5*%pdia%+1
&local ext_pon = .65*%cdia%
$
$*********************************************      enter surfact menu
$
&surface
$
$*********************************************      generate a pontoon
$
pontoon S -%len%/2  %beam%/2 %ponhgt 0 -length %len -npoin %npp -dia %pdia
$
$*********************************************      generate two columns
$
column sf -%len%/2  %beam%/2  -height %cdep -npoin %npc -dia %cdia
column sa +%len%/2  %beam%/2  -height %cdep -npoin %npc -dia %cdia
$
$*********************************************      join
$
suplot
union s sf temp
delete s sf
suplot temp sa
union temp sa stbd
delete temp sa
suplot stbd
$
$*********************************************      reflect
$
reflect stbd port y
$
$*********************************************      fwd pontoon
$
pont F -%len%/2  %beam%/2 %ponhgt -90 -length %len -npoin %npp -dia %pdia
suplot stbd port f
$
$*********************************************      join
$
union stbd f temp
union port temp ttemp
delete stbd f port temp
suplot ttemp
$
$*********************************************      aft pontoon
$
pontoon a  %len%/2  %beam%/2 %ponhgt -90 -length %len -npoin %npp -dia %pdia
suplot ttemp a
union ttemp a tlp
suplot tlp
$
$*********************************************      rename
$
rename tlp -equiv .1
$
$*********************************************      emit
$
emit tlp -body
emit tlp  -piece '-diftype 3ddif -cs_curr 1 1 1 -cs_wind 1 1 1'
$
$*********************************************      all done
$
end
&fini