$
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$
$       --------------------   db102  ----------------------
$
$  This comi file will generate a panel model of db102. If the
$  parameter detail is set to .true., the model will be reasonably
$  detailed, if not the model will have minimal panels.
$
$  The file DB102.PPOUT contains the mesh.
$
$
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$
$*********************************************      basic parameters
$
&dimen -dimen meters m-tons
&device -pri devi
&set detail = .false.
$
$*********************************************      plot macro
$
&set plot = .true.
&macro suplot nams
   &if %plot &then
      &selec :n -sel %nams
      &picture iso -parent :n
      &picture top -parent :n
      &picture side -parent :n
   &endif
&endmacro
$
$*********************************************      enter &surface
$
&surface
$
$*********************************************      build stbd side
$
&set dep    = 24
&set np     = 4
&set theta  = &number(real 90/%np%)
&set dstab  = &number(real 1.9*10)
&set dstbc  = &number(real 1.9*9)
&set leng   = 22.8
&set clsbx  = &number(real %leng%+%dstab%)
&set clscx  = &number(real 2*%leng%+%dstab%+%dstbc%)
&set simple = 22.8 32.3 %clsbx% %clsbx%+%leng%       \
                  %clscx% %clscx%+%leng%  119.7 153.9
&set complx = 22.8 .5*(22.8+%clsbx%) %clsbx%     \
                  %clsbx%+.5*%leng% %clsbx%+%leng%           \
                  %clsbx%+%leng% .5*(%clsbx%+%leng%+%clscx%) \
                  %clscx%  %clscx%+.5*%leng%                 \
                  %clscx%+%leng% 119.7 128.25                \
                  136.85 145.35 153.9
$
$*********************************************      pontoon
$
&cutype Building Stbd Pontoon
block h1s -locat  0 30.1 0
      plane 0 -RECT 11.4 13.6 28
      plane 11.4 -RECT 5.7 13.6 28
      &if %detail &then
         plane %complx -RECT 0 13.6 28
      &else
         plane %simple -RECT 0 13.6 28
      &endif
end block
$
$*********************************************      aft column
$
&cutype Building aft column
&set leng  = 34.2
&set brdt  = 27.5
&set bilgd = &number(real (%brdt%-6)/2)
&set top   = &number(real %leng%-3)
&set bot   = 3
block coll -LOC 119.7 30.1 13.6+%dep 0 90
      &if %detail &then
         plane 0 25 -circ %bilgd% %bot  3 0  %theta% %np% \
                    -circ %bilgd% %top  3 90 %theta% %np%
      &else
         plane 0 25 -rect 0 %leng %brdt
      &endif
end_block
$
$*********************************************      fwd column
$
&cutype Building fwd column
&set leng  = 22.8
&set brdt  = 22.8
&set bilgd = &number(real (%leng%-6)/2)
&set top   = &number(real %leng%-3)
&set bot   = 3
block colsa -LOC 0 32.6 13.6+%dep 0 90
      &if %detail &then
         plane 0 25.9 -circ %bilgd% %bot  3 0  %theta% %np% \
                      -circ %bilgd% %top  3 90 %theta% %np%
      &else
         plane 0 25.9  -rect 0 %leng %brdt
      &endif
end_block
$
$*********************************************      interm columns
$
&cutype Building intermediate columns
move_block colsa colsb %clsbx%
move_block colsa colsc %clscx%
$
$*********************************************      union
$
&cutype joining to make stbd side
union coll h1s h1cll
union h1cll colsa h2col
union h2col colsb h3col
union h3col colsc stbd
delete_block h1s coll h1cll h2col h3col colsa colsb colsc
$
$********************************************       reflect to port
$
reflect_block stbd port y
$
$*********************************************      define deck
$
block deck -loca 0 0 13.6+23.9
         plane -2 156 -rect 0 10 88.4
end block
$
$********************************************       join
$
&cutype joining stbd to Deck
union stbd deck half
&cutype joining port to Deck
union half port db102
delete deck half port stbd
$
$********************************************       plot
$
suplot db102
$
$********************************************       rename & emit
$
rename db102
emit db102 -body
emit db102 -piece '-diftype 3ddif -cs_curr 1 1 1 -cs_wind 1 1 1'
$
$********************************************       all done
$
&fini