$
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$
$
$   ----------    JACKET LOWER/UPEND COMMANDS  ------------
$
$    This is a relative complex example. In essence, this set of
$ commands simulate lowering a jacket into the water and upending
$ it. At some point during the lowering process, a frequency domain
$ simulation is performed. To accomplish this task, two different
$ slings and two different processes are defined. At the conclusion,
$ a structural analysis of selected events during the lowering and
$ upending is performed.
$
$    To look at either the lowering or the upending alone, one can
$ essentially comment out the part which is not needed. Also, the
$ structural post-processing presented here is trivial. In reality,
$ one should add other commands in this menu to obtain what he really
$ wishes to investigate.
$
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$
$
$*********************************************      define misc. params
$
&device   -g_default file -oecho no
&dimen -DIMEN FEET KIPS
&TITLE Jacket Lower/Upend Analysis
$
$*********************************************      define water depth
$
&default -DEPTH 186.0
$
$*********************************************      read model
$
INMODEL -offset
$
$*********************************************      set weight
$
&apply  -margin str@ 5
&apply @
$
$*********************************************      define lowering process
$
&describe process lower
$
$*********************************************      define environment
$
&data environment
   environment sea -sea issc 90 3 7 -use_mean
end_&data
$
$*********************************************      move part
$
&describe part jacket -move 0 0 0 *j0501 *j1001 *j0503 *j1003
&INSTATE -LOCATE jacket 0 0 10
$
$*********************************************      define lowering sling
$
MEDIT
   &describe part ground
   *boom 199.20      0.00    755.42
   ~boo SLING 3 -len 300
   ~LSL SLING 3 -len 400
   CONNECTOR boom1  ~boo *boom
   CONNECTOR LS0602 ~LSL *j0602
   CONNECTOR LS0604 ~LSL *j0604
   CONNECTOR LS1002 ~LSL *j1002
   CONNECTOR LS1004 ~LSL *j1004
   assembly t-h_definition boom1 LS0602 LS0604 LS1002 LS1004 -initial
END
&instate -move -sl
&status tip-hook
&status f_connector
$
$*********************************************      lower into water
$
STATIC_PROCESS
   BEGIN -CHEIGHT
   LIFT -5 -SHEIGHT -50
END
$
$*********************************************      lower post-processing
$
PRCPOST
   STP_STD
END
$
$*********************************************      freq. domain
$
&INSTATE -EVENT 3
&equi
&status config
&status f_connector
$
$*********************************************      freq. post-processing
$
freq_response
   rao -PERIOD 5 6 7 8 9 10 11 -HEADING 90
   fr_point
      REPORT
   END
   fr_cforce LS0602
      REPORT
   END
   st_cforce @ SEA
      REPORT
   END
END
$
$*********************************************      upending process
$
&DESCRIBE PROCESS UPEND
$
$*********************************************      define upend sling
$
MEDIT
   ~USL SLING 4 -len 80
   CONNECTOR boom2  ~boo *boom
   CONNECTOR US0601 ~USL *j0601
   CONNECTOR US0603 ~USL *j0603
   CONNECTOR US0602 ~USL *j0602
   CONNECTOR US0604 ~USL *j0604
   assembly t-h boom2 us0601 us0603 us0602 us0604 -deactivate -initial
END
&status tip-hook
&status f_connector
$
$*********************************************      upend
$
STATIC_PROCESS
   &INSTATE JACKET -GUESS *j0702 *j0704 *j0902
   BEGIN
   LIFT  5 -SHEIGHT  35
   flood a@ 10 100 -cheight
   flood b@ 10 100 -cheight
END
$
$*********************************************      upend post
$
PRCPOST
   STP_STD
   tank_bal
      report
      end
END
$
$*********************************************      structural
$
STRUCTURAL
   &DESCRIBE process upend
   LCASE -PROCESS upend-3 3
   &DESCRIBE process lower
   LCASE -PROCESS  lower-1 1
   LCASE -RAO
   SSOLVE -NONLINEAR
END
$
$*********************************************      structural post
$
STRPOST
   &SELECT :CLASS -select @ -except ~'$'WA@
   CASES -SPECTRA SEA
   &select :load -select sea@ upend-3 lower-1
   RESTRAINT   -CLASS :CLASS -load :load -detail
END
$
$*********************************************      all done
$
&FINISH