$
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$
$
$   ----------    JACKET TWO BLOCK UPEND COMMANDS  ------------
$
$    This is a relatively complex example of a two block upend. The
$    jacket model used here is a tripod with the legs flooded.
$    Therefore, the jacket never floats freely, and is rotated
$    to vertical by manipulating the load in the side lift slings
$    and upending slings simultaneously.  It is assumed the side
$    lift slings are attached to the main block and the upending slings
$    are attached to the auxiliary block of the crane of a derrick
$    barge.
$
$    The analysis is performed in two stages: one for the side lift
$    and lowering of the jacket to the water, and one for the upending.
$    Extensive use is made of loops and macros for simplicity.  The
$    side lift/lowering analysis is performed in random waves.  A
$    structural analysis of selected load cases is also performed.
$
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$
$*********************************************      define misc. params
$
&device -g_default file   -oecho n
&dimen -DIMEN FEET KIPS
&TITLE Two Block Upend Analysis
$
$*********************************************      define water depth
$
&default -depth 138.0
$
$*********************************************      read model
$
INMODEL  -offset
$
$*********************************************      set weight
$
&apply  -margin str@ 6
&apply  -percent @ 100
$
$*********************************************      weight summary
$
&summary
   categ_sum
end
$
$*********************************************      define environment
$
&data environment
   environment sea -sea issc 90 5 7 -use_mean yes
end_&data
$
$*********************************************      reposition jacket
$
&describe process sidelift
&describe part jacket -move 0 0 0 *j403 *j103 *j401 *j101
&instate -locate jacket 0 0 10
&status config
$
$*********************************************      define sidelift slng
$
medit
   ~bo1 sling 10 -length 200.00 -density 0.001 -emodulus 15000.
   ~ls3 sling 4  -length 157.31 -density 0.001 -emodulus 15000.
   ~ls1 sling 4  -length 140.20 -density 0.001 -emodulus 15000.
   &describe part ground
   *mainhk 0 0 250 -location &body(cg jacket -g)
   &type Location of *mainhk &point(coordinates *mainhk -g)
   connector mainln ~bo1 *mainhk
   connector ls305 ~ls3 *j305
   connector ls105 ~ls1 *j105
   t-h_definition main mainln ls305 ls105 -init
end
$
&picture iso
&status tip-hook -hard
&status f_connect -hard
$
$*********************************************      lower into water
$
&loop j 1 30
   &instate -move jacket 0 0 -4 0 0 0 -sl_set
   &equi -tol 0.05 0.005
   &event_store %j%
   &set info = &connector(mainln -tension)
   &type Event %j%  Hook Load = &token(2 %info%)
   &exit &token(2 %info%) .le. 400.
&endloop
rpt
$
$*********************************************      lower post process
$
postpro
$
$*********************************************      freq. domain
$
freq_response
   rao -period 5 6 7 8 9 10 11 -heading 90
   fr_point
      report
   end
   fr_cforce ls305
      report
   end
   st_cforce @ sea
      report
   end
end
$
$*********************************************      define upend sling
$
&describe process upend
medit
   ~bo2 sling 10 -length 600.00 -density 0.001 -emodulus 15000.
   ~usl sling 4 -length 100 -emod 15000.
   &describe part ground
   *auxhk  10 0 10 -reference *mainhk
   &type Location of *auxhk = &point(coordinates *auxhk -g)
   connector auxln ~bo2 *auxhk
   connector us401 ~usl *j401
   connector us403 ~usl *j403
   connector us405 ~usl *j405
   t-h_definition up auxln us401 us403 us405  -initial
end
$&instat -sl
$
$*********************************************      initial position
$
&set stit =  Initial Position
&cutype %stit
&set J    = 0
new_pos 0 0
$
$*********************************************      rotating
$
&set stit =  Rotating Stage
&cutype %stit
&set inc = 10
&loop I %inc% 60   %inc%
   new_pos 0 -%inc -point *j405
&endloop
$
$*********************************************      lifting
$
&set stit =  Lifting for Clearance
&cutype %stit
&loop I 5 10 5
   new_pos %i 0  -point *j405
&endloop
$
$*********************************************      rotating again
$
&set stit = Rotating Again
&cutype %stit
&describe body -ignore rz
&loop I 5 20 5
   new_pos 0 -%i -ry 85  -point *j405
   &exit %done
&endloop
&describe body -ignore
$
$*********************************************      release lower slng
$
&set stit = Release Lowering Sling
&cutype %stit
&connector main -inactive
&instat -move -sl
new_pos 0 0  -point *j405
$
$*********************************************      lower to mudline
$
&set stit = Lower to Mudline
&cutype %stit
&loop I 2 18 2
   new_pos -%i 0 -bot 138+2 -point *j405
   &exit %done
&endloop
&subtitle
$
$*********************************************      upend post
$
postpro
$
$*********************************************      structural
$
structural
   &describe process sidelift
   lcase -rao
   lcase -process lift-1 1
   &describe process upend
   lcase -process upend-3 3
   ssolve -nonlinear
end
$
$*********************************************      structural post
$
strpost
   &select :class -select @ -except ~'$'wa@
   cases -spectra sea
   &select :load -select sea@ lift-1 upend-3
   restraint loads -class :class -load :load -detail
   beam  code -class :class -load :load \
              -standard 1 1e10 0 1 -code api
   joint code -class :class -load :load \
              -standard 1 1e10 0 1
end
$
$*********************************************      all done
$
&FINISH