$
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$
$                 Sample Problem Showing Ballasting and
$                             Hydrostatic Options
$
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$
$
$*********************************************      set basic parameters
$
&device -g_default file  -oecho no
&dimen -DIMEN FEET KIPS
&TITLE Ballasting and Stability Example
$
$*********************************************      READ MODEL
$
INMODEL
$
$*********************************************      ENTER HYDROSTATIC MENU
$
HSTATICS
   &set sut = STG-7     
   &apply @ 0 h109 100
   &subtitle %sut
   &instate -condition 27.5 0 -1.62
   &APPLY stg-7   
   &status loadg
   &compartment -percent  8/W 100 7PW 31.82 7SW 32.38 9// 100 9PW 87.75 \
                    10PW 32.51 10SW 33.06
   &select :stg7 -select 2// 4// 8/w 7pw 7sw 9// 10//
   &cmp_bal h109 :stg7
   equi
   rep_sum -initial
$
$
   &set sut = STG-8     
   &apply @ 0 h109 100
   &subtitle %sut
   &instate -condition 27.5 0 -1.62
   &APPLY stg-8   
   &status loadg
   &select :stg8 -select 2// 4// 8/w 7pw 7sw 9// 10//
   &cmp_bal h109 :stg8
   equi  
   rep_sum 
$
$*********************************************      Lift OFF stage
$
   &apply @ 0 h109 100
   &set sut = LIFT OFF
   &subtitle %sut
   &instate -condition 27.5 0 -1.62
   &APPLY LIFT-OFF
   &status loadg
   &compart -percent 2// 0 4// 0
   &compartment -percent  8/W 100 7PW 31.82 7SW 32.38 9// 100 9PW 87.75 \
                    10PW 32.51 10SW 33.06
$
$*********************************************      long. strength
$
   equi
   moment -allow 24.00 1.
      report
      vlist
      plot 1 4 -RAX 5 -legend  2 Deflection \
               -t_x 'Longitudinal Location (ft)' \
               -t_right 'Deflection (Inches)' -no
   end
   rep_sum 
$
$*********************************************      intact stability
$
   &subtitle Intact Stability North Tow
   rarm 2.5 25 -echo n -wind 100
      report
      vlist
      plot 2 6 8 -RAX 10 -legend 2 'Wind Heel Arm' \
                 -t_x 'Roll (Degrees)' \
                 -t_left 'Righting Arm (ft)' -no
   end
$
$*********************************************      damaged stability
$
   &subtitle DAMAGED STABILITY NORTH TOW ..TANK 3PW FLOODED
   &compartment -flood 3PW
   equi
   &status B_W -HARD
   &subtitle COMPUTE BALLAST TO REGAIN TOW CONFIGURATION IN DAMAGED CONDITION
   &instate -condition 27.5 0 -1.62
   &status b_w -hard
   &status compartment -hard
   &event_store 1
   &select :comp -select 7/W 10/W 8// 12//
   &CMP_BAL H109 :comp 
   &status b_w -hard
   moment -allow 24.00 1.
      view -record 1 15  -SEL @
      report
   end
$
$*********************************************      restore condition
$
   &subtitle RETURN TO INITIAL CONFIGURATION   NORTH TOW
   &instate -event 1
   &compartment -no_flood 3PW
   equi
   &status B_W
end
$
$*********************************************
$
&status compartment
prcpost
   tank_bal
       report
       end
end_prcpost
$
$*********************************************
$
&FINISH