$
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$
$
$   ----------    Multiple Curves On A Plot   --------
$
$    This examples shows how to "gather" curves and combine them
$    on a single plot. The particular data used are the values of
$    spectra for different peak periods.
$
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$
$
$*********************************************      set basics
$
&dimen -dimen feet kips
&device   -g_default device
&TITLE Spectral Values For Different Peak Periods
$
$*********************************************      Read Model
$
inmodel
$
$*********************************************      Set Condition
$
&instate -con 10 0 0000
&weight -compute 27  32 97 97
&status
$
$*********************************************      Frequency Domain
$
hydro
   g_press -heading 90
end
$
$*********************************************      Define Report Pts.
$
&dcptime
$
$*********************************************      Frequency Post
$
freq_resp
$
$*********************************************      response
$
   rao
$
$*********************************************      gather data
$
   &set  pper =  5.5 6.0 6.5 7.0 7.5 8.0 8.5
   &loop pp ( %pper ) 
      sp_point -sea issc 90 10 %pp  -sp_type peak
         vlist
         report
         set_var per   -column 2 
         set_var s%pp  -column 3 
         end
   &endloop
end
$
$*********************************************      plot it 
$
&buildg -s
  Period %pper
    &loop k 1 &token(n %per)
       &set row = &token(%k %per) 
       &loop pp ( %pper ) 
          &set s   = &token(%k %(s%(pp)) ) 
          &set row = %row %s
       &endloop
       %row
    &endloop
    end
    plot 1 2 3 4 5 6 7 -n -t_left "Spectral Values"
end
$
$*********************************************      All done
$
&finish