$
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$
$   This is an example of computing righting arms of a body with
$   connectors.
$
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
$
$
$***************************************         basic stuff
$
$
$****************************************       set device stuff
$
&dimen -dimen feet kips
&device   -oecho no -pri device
$
$****************************************       setup up
$
inmodel
&instate -condition 9
&weight -compute 5 32 .29*400 .29*400
$
$****************************************       initialize results
$
&set weight = &body(weight)
&set inc    = 1
&set angle  = 0
&set arm    = 0
$
$****************************************      define connectors & moment
$
medit
   ~wire b_cat  4.19 -dep 500 -len 4000 -buoy 0 -wtpl .008 \
                     -b_tens 500
   connector ss ~wire   *ss  -anc   45   20
   connector BS ~wire   *bs  -anc  135   20
   connector bp ~wire   *bp  -anc  -45   20
   connector sp ~wire   *sp  -anc -135   20
   &describe load moment
   &describe body barge
   *orig 0 0 0
   #mx *orig 0 0 0 %weight 0 0
end
$
$****************************************      gen curve
$
&loop k 1 25
   &type k = %k
   &set a_new = %k*%inc
   &apply -percent -force @ 100*%a_new
   &equi -tol 1e-5
   &status force
   &event %k
   &set arm   = %arm    %a_new
   &set a_new = &body(location)
   &set a_new = &token(4 %a_new)
   &set angle = %angle  %a_new
&endloop
$
$****************************************      report results
$
&build -brief
   Roll Angle
   Righting Arm
 
   &loop k 1 &token(n %angle)
      &token(%k %angle) &token(%k %arm)
   &endloop
 
   plot 1 2 -no
   view 1 2 -hard
$
$****************************************      all done
$
&fini